Getrennte Senderlisten für DVB-T und DVBV-Client

[Mikefield]

Hallo Forum!

Habe da mal noch eine Frage zu den Sendergruppen bzw. -listen. Ich pendle immer von A nach B, wobei ich in A die Woche über

DVB-T habe und am WE in B den DVBV Client. Nun möchte ich aber an beiden Standorten die gleichen Sendernummern haben.

Das heißt, ARD fängt bei 1 an und nicht bei 23. Wenn ich bei DVB-T 22 Sender empfange so würde dann der DVBVClient bei 23

anfangen wenn ich das so richtig verstanden habe. Durch die Vergabe der Gruppenlisten mit A und B schließt ja die andere nicht

aus oder? Eine Möglichkeit, pro Hardwaredevice eine andere Senderliste wäre hierbei wünschenswert. Ist so etwas optional geplant?

Das es Sinn macht eine komplette Senderliste zu haben verstehe ich ja, aber nicht in meinem Fall.

 

mf

[Lars_MQ]

2 batch dateien

 

startA.bat + Startb.bat

 

zwei links auf dem desktop

 

in den batchdateien:

 

kopiere channelsA.dat nach channels.dat und entsprechend für B

starte DVBViewer.

 

 

Ein wenig nachdenken und schon hat man eine lösung. Das hilft aber weder bei timern noch beim epg

[Mikefield]

Hallo Lars_MQ! Das mit den Batchdateien hatte ich für mich schon als Umbogen grob skizziert. Allerdings reicht da eine Batch. Kurz per IPConfig abfragen welches

Standardgateway aktiv ist und entsprechend handeln. Ich wollte aber sicher sein, bevor ich mir die Arbeit mache

Danke!

 

mf

[Mikefield]

So, es ist vollbracht. Wenn jemand ein ähnliches Problem hat, hier ist die Lösung. Einzige Bedingung:

Es müssen pro Standort unterschiedliche IP-Adressen für das Standardgatway vergeben worden sein.

 

@echo off & setlocal enabledelayedexpansion

:Variablen
REM Hier werden die Variablen zur weiteren Verarbeitung gesetzt. 
REM Bitte beachten, daß die Variablen zu ChDat1 und ChDat2 den 
REM gespeicherten Kanallisten entspricht! 
REM Außerdem müsen die Variablen GwDat1 und GwDat2 für die 
REM StandardGateWays angepaßt werden!  
Set "ChDat=Unknown"
Set "ChDat0=Channels.dat"
Set "ChDat1=Rhein-Main.dat"
Set "ChDat2=Netzwerk.dat"
Set "ChOld0=Channels_Old.txt"
Set "GwDat1=192.168.1.1"
Set "GwDat2=192.168.150.1"

:Check_ChDat
REM Prüfen der korrekten Dateinamen zu den Variablen ChDat1 und ChDat2.
If Not Exist %ChDat1% set "%ChDat1%=NoChDAt1" & goto Wrong_ChDat
If Not Exist %ChDat2% set "%ChDat2%=NoChDAt2" & goto Wrong_ChDat

:Check_ChOld
REM Abfrage der alten Kanalliste. Der Name wurde beim letzten 
REM Aufruf in die oben mit ChOld festgelegten Datei hinterlegt. 
REM Dadurch gehen zwischenzeitlich getätigten Änderungen nicht 
REM verloren!
For /F "Tokens=*" %%A IN (%ChOld0%) Do Set OldCh=%%A
Echo Alte Liste= %OldCh%

:Check_GateWay 
REM Abfrage des StandardGateWays über IPConfig
For /F "Tokens=1,2 Skip=1 Delims=:" %%a In ('IPCONFIG.EXE') Do (
 set Gateway=%%a
 If "!Gateway:~8,15!"=="Standardgateway" (
for /F "Tokens=1 Delims= " %%i In ("%%b") do (
  set "SGW=%%i"
)
 )
)

:Compare_Gateway
REM Prüfen des StandardGateWays und setzen des korrekten Standorts. 
IF "%SGW%"=="%GWDAT1%" Set "ChDat=%ChDat1%"
IF "%SGW%"=="%GWDAT2%" Set "ChDat=%ChDat2%"
IF /I "!ChDat!"=="Unknown" Goto Unknown_SGW

:Copy_Channel_Files
REM Kopiere die entsprechenden Kanallisten
If "%OldCh%"=="%ChDat%" (
 Echo "%OldCh%" gleich "%ChDat%"
 Goto No_Chg
) ELSE (
 Echo Kopiere %ChDat0% nach %OldCh%
 Copy %ChDat0% %OldCh% >nul
 Echo Kopiere %ChDat% nach %ChDat0%
 Copy %ChDat% %ChDat0% >nul
 Echo %ChDat%> %ChOld0%
)
Goto Start_DVBV

:Wrong_ChDat
REM Fehlermeldung bei falschen Variablen ChDat1 und ChDat2
ECHO Mindestens eine in den Variablen ChDat1 und ChDat2 angegebenen 
ECHO Dateien wurden nicht gefunden: 
IF "!%ChDat1%!"=="NoChDAt1" Echo Der Eintrag bei ChDat1 ist fehlerhaft
IF "!%ChDat2%!"=="NoChDAt2" Echo Der Eintrag bei ChDat2 ist fehlerhaft
Echo Bitte die Eintr„ge in den Variablen korrigieren. 
Pause
Goto :EOF

:Unknown_SGW
REM Fehlermeldung bei unbekanntem SatandardGateWay. Die IP-Adresse wird 
REM in die Datei New_SGW.txt gespeichert. 
Echo %Date% %Time% Info: %SGW% >> New_SGW.txt
Echo Unbekanntes StandardGateWay 
Pause
Goto :EOF

:Start_DVBV
REM Hier wird nun der DVBViewer gestartet, es können auch Startparameter 
REM gesetzt werden
Echo Starte DVBViewer
rem Start DVBViewer.exe
Exit /b

:No_Chg
REM Meldung wenn keine Änderung erforderlich ist
Echo Aktuelles Gateway stimmt mit alter Liste �berein, daher ist keine 
Echo Žnderung notwendig
goto :EOF

 

mf